Members

Technology Zones

IBM Learning Center

Articles

Hosted By

MaximumASP

Info
Rated
Read 65,950 times
3 comments

Related Categories

Close a message box automatically

James Crowley

Many programs display message boxes that automatically close after a period of time, including printer errors and closing outlook. In VB, this is more complicated than it should be, but still possible. Here's how.

'Module Code
Private Declare Function KillTimer Lib "user32" (ByVal hWnd As Long, ByVal nIDEvent As Long) As Long
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare Function SetForegroundWindow Lib "user32" (ByVal hWnd As Long) As Long
'// Message we receive telling us to close the message box
Public Const NV_CLOSEMSGBOX As Long = &H5000&
Public Sub TimerProc(ByVal hWnd As Long, ByVal uMsg As Long, ByVal idEvent As Long, ByVal dwTime As Long)
    '// this is a callback function.  This means that windows "calls back" to this function
    '// when it's time for the timer event to fire
    '// first thing we do is kill the timer so that no other timer events will fire
    KillTimer hWnd, idEvent
    '// select the type of manipulation that we want to perform
    Select Case idEvent
    Case NV_CLOSEMSGBOX '// we want to close this messagebox after 4 seconds
        Dim hMessageBox As Long
        '// find the messagebox window
        '// change the text to whatever the title of the message box is
        hMessageBox = FindWindow("#32770", "Self Closing Message Box")
        '// if we found it make sure it has the keyboard focus and then send it an enter to dismiss it
        If hMessageBox Then
            Call SetForegroundWindow(hMessageBox)
            '// this will result in the default option being chosen
            SendKeys "{enter}"
        End If
    End Select
End Sub


'Form Code
Private Declare Function SetTimer Lib "user32" (ByVal hWnd As Long, ByVal nIDEvent As Long, ByVal uElapse As Long, ByVal lpTimerFunc As Long) As Long

Private Sub cmdShowMsg_Click()
    '// this shows a messagebox that will be dismissed after 4 seconds
   
    '// set the callback timer and pass our application defined ID (NV_CLOSEMSGBOX)
    '// set the time for 4 seconds (4000 microseconds)
    SetTimer hWnd, NV_CLOSEMSGBOX, 4000, AddressOf TimerProc
   
    '// call the messagebox function
    If MsgBox("Watch this message box close itself after four seconds. The printer is out of paper. Retry or Cancel? (Example)", vbRetryCancel + vbDefaultButton1, "Self Closing Message Box") = vbRetry Then
        MsgBox "Retry!"
    Else
        MsgBox "Cancel"
    End If
 
End Sub

James first started writing tutorials on Visual Basic in 1999 whilst starting this website (then known as VB Web). Since then, the site has grown rapidly, and James has written numerous tutorials, articles and reviews on VB, PHP, ASP and C#. In October 2003, James formed the company Developer Fusion Ltd, which owns this website, and also offers various development services. In his spare time, he's a 3rd year undergraduate studying Computer Science in the UK. He's also a Visual Basic MVP.

Comments

Read Comments | Post Comment

  • A couple of mods

    Posted by jonesmabel on 03 Nov 2003

    I could not get it to work in Outlook2000 until I added TimerID as long then..
    TimerID=SetTimer (hWnd, NV_CLOSEMSGBOX, 4000, AddressOf TimerProc)
    then change the line
    Case NV_CLOSE...

  • asdf

    Posted by guitargod311 on 03 Jun 2002

    this is way to complicated....

    call me stupid, but couldn't you use this:

    Module:

    Declare Sub Sleep Lib "kernel32" (ByVal dwmilliseconds As Long)

    Form Code:

    Private Sub Form_Load()
    msg...

  • It works on some! Can adjust for more ?

    Posted by adclick on 07 Dec 2001

    First off Thanks for this code it works well for some message boxes.

    I can change this line :
    hMessageBox = FindWindow("#32770", "Self Closing Message Box")
    to this
    hMessageBox = FindWindow("#32...